Ticket #3337: weathercomXML.pl

#!/usr/bin/perl -w

use strict;

use Data::Dumper;
use Getopt::Std;
use LWP::Simple;
use XML::Simple;

our ($opt_d, $opt_l, $opt_t, $opt_T, $opt_u, $opt_v);

my $name = 'weathercomXML';
my $version = 0.1;
my $author = 'Simon Flood';
my $email = 'simon@floodfamily.info';
my $updateTimeout = 15*60;
my $retrieveTimeout = 30;
my @types = ('3dlocation', '6dlocation', 'appt', 'cclocation', 'date-0',
             'date-1', 'date-2', 'date-3', 'date-4', 'date-5', 'desc1',
             'desc2', 'desc3', 'dewpoint', 'high-0', 'high-1', 'high-2',
             'high-3', 'high-4', 'high-5', 'icon-0', 'icon-1', 'icon-2',
             'icon-3', 'icon-4', 'icon-5', 'latitude', 'longitude', 'low-0',
             'low-1', 'low-2', 'low-3', 'low-4', 'low-5', 'observation_time',
             'pressure', 'relative_humidity', 'station_id', 'temp',
             'updatetime', 'visibility', 'weather', 'weather_icon', 'wind_dir',
             'wind_gust', 'wind_speed', 'wind_spdgst');
my $dir = './';
my $unit;

my $base_url = "http://xoap.weather.com/";
my $weather_url = $base_url . "weather/local/";
my $query_url = $base_url . "search/search";

getopts('d:ltTu:v');

if (defined $opt_d) {
    $dir = $opt_d;
}

if (defined $opt_l) {
    my $response = get $query_url . "?where=" . $ARGV[0];
    my $xml = XMLin($response);
    foreach my $id (sort keys %{$xml->{loc}}) {
        print $id, "::", $xml->{loc}->{$id}->{content}, "\n";
    }
    exit 0;
}

if (defined $opt_t) {
    foreach (@types) {
        print; print "\n";
    }
    exit 0;
}

if (defined $opt_T) {
    print "$updateTimeout,$retrieveTimeout\n";
    exit 0;
}

if (defined $opt_u) {
    if ($opt_u =~ /ENG/) {
        $unit = "s";
    } elsif ($opt_u =~ /SI/) {
        $unit = "m";
    }
}

if (defined $opt_v) {
    print "$name,$version,$author,$email\n";
    exit 0;
}

my $loc = shift;

if (!(defined $unit && defined $loc && !$loc eq '')) {
    die "Invalid usage";
}

my $response = get $weather_url . $loc . '?cc=*&dayf=6&unit=' . $unit;
die unless defined $response;

my $xml = XMLin($response);

foreach (@types) {
    my $label;
    my $value;

    $label = $_;

    if (/[36]dlocation/) {
        $value = $xml->{loc}->{dnam};
    } elsif (/appt/) {
        $value = $xml->{cc}->{flik} . chr(176) . $xml->{head}->{ut};
    } elsif (/cclocation/) {
        $value = $xml->{cc}->{obst};
    } elsif (/date-([0-5])/) {
        $value = $xml->{dayf}->{day}->[$1]->{t};
    } elsif (/desc([123])/) {
        $value = $xml->{dayf}->{day}->[$1-1]->{part}->[0]->{t};
    } elsif (/dewpoint/) {
        $value = $xml->{cc}->{dewp} . chr(176) . $xml->{head}->{ut};
    } elsif (/high-([0-5])/) {
        $value = $xml->{dayf}->{day}->[$1]->{hi};
    } elsif (/icon-([0-5])/) {
        $value = $xml->{dayf}->{day}->[$1]->{part}->[0]->{icon} . '.png';
    } elsif (/latitude/) {
        $value = $xml->{loc}->{lat};
    } elsif (/longitude/) {
        $value = $xml->{loc}->{lon};
    } elsif (/low-([0-5])/) {
        $value = $xml->{dayf}->{day}->[$1]->{low};
    } elsif (/observation_time/) {
        $value = $xml->{cc}->{lsup};
    } elsif (/pressure/) {
        $value = $xml->{cc}->{bar}->{r} . ' ' . $xml->{head}->{up};
    } elsif (/station_id/) {
        $value = $loc;
    } elsif (/temp/) {
        $value = $xml->{cc}->{tmp} . chr(176) . $xml->{head}->{ut};
    } elsif (/relative_humidity/) {
        $value = $xml->{cc}->{hmid} . ' %';
    } elsif (/updatetime/) {
        $value = $xml->{dayf}->{lsup};
    } elsif (/visibility/) {
        $value = $xml->{cc}->{vis} . ' ' . $xml->{head}->{ud};
    } elsif (/wind_dir/) {
        $value = $xml->{cc}->{wind}->{t};
    } elsif (/weather$/) {
        $value = $xml->{cc}->{t};
    } elsif (/weather_icon/) {
        $value = $xml->{cc}->{icon} . '.png';
    } elsif (/wind_gust/) {
        $value = $xml->{cc}->{wind}->{gust};
        if ($value ne 'N/A') {
            $value .= ' ' . $xml->{head}->{us};
        }
    } elsif (/wind_spdgst/) {
        $value = "$xml->{cc}->{wind}->{s} ($xml->{cc}->{wind}->{gust}) $xml->{head}->{us}";
    } elsif (/wind_speed/) {
        $value = $xml->{cc}->{wind}->{s} . ' ' . $xml->{head}->{us};
    }

    print $label . "::" . $value . "\n";
}